blob: 1b89503df2a15d73d1453d6f3d4e6c2030e77ab0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
{
description = "My flake configuration";
inputs = {
nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
# TODO
# nixpkgs#deno in nixpkgs-unstable branch is broken for now.
nixpkgs_deno.url = "github:NixOS/nixpkgs/1b36b17a09686ff51e2944334da1cf308fa81e48";
flake-utils.url = "github:numtide/flake-utils";
treefmt-nix = {
url = "github:numtide/treefmt-nix";
inputs.nixpkgs.follows = "nixpkgs";
};
nur-packages = {
url = "github:nsfisis/nur-packages";
inputs.nixpkgs.follows = "nixpkgs";
};
home-manager = {
url = "github:nix-community/home-manager/master";
inputs.nixpkgs.follows = "nixpkgs";
};
};
outputs =
{
nixpkgs,
nixpkgs_deno,
flake-utils,
treefmt-nix,
nur-packages,
home-manager,
...
}:
flake-utils.lib.eachDefaultSystem (
system:
let
pkgs = import nixpkgs { inherit system; };
treefmt = treefmt-nix.lib.evalModule pkgs ./treefmt.nix;
in
{
formatter = treefmt.config.build.wrapper;
}
)
// {
homeConfigurations = (
let
readJSON = p: builtins.fromJSON (builtins.readFile p);
mkHomeConfiguration =
{
profile,
flake,
...
}:
home-manager.lib.homeManagerConfiguration {
pkgs = import nixpkgs { system = flake.system; };
extraSpecialArgs = {
nixpkgs_deno = import nixpkgs_deno { system = flake.system; };
env = flake.env;
nurpkgs = nur-packages.legacyPackages.${flake.system};
};
modules = [
./home-manager/modules/common.nix
./home-manager/modules/${profile}.nix
];
};
mkHomeConfigurationFromJSON = p: mkHomeConfiguration (readJSON p);
in
{
akashi = mkHomeConfigurationFromJSON ./mitamae/node.akashi.json;
pc168 = mkHomeConfigurationFromJSON ./mitamae/node.pc168.json;
}
);
};
}
|
